Amiga Plus Special 18/AMIGAplus Sonderheft 18 (1999)(ICP)(DE)[!].iso/PD/Anwendungen/Warp3D/Install_Warp3D

Text File | 1999-01-03 | 6KB | 243 lines

; $VER: Installation script for Warp3D 1.0 ( 5. Dezember 1998)
; © Thomas & Hans-Jörg Frieden
; Created with GoldED 5.0

; check if we are running under correct OS

(if (< (/ (getversion) 65536) 39)
    (
        (abort "Incorrect OS version (software requires OS 39 or better )!")
    )
)

; error handling

;
; Procedure to copy a single library
(procedure P_copy_single arg1 arg2 arg3
        (copylib
                (confirm)
                (prompt arg3)
                (help @copylib-help)
                (source arg1)
                (dest arg2)
                (optional "oknodelete" "askuser")
        )
)

(onerror
    (if (> @ioerr 0)
        (
            (message
                ("An error has occurred during installation. Please check the log file to understand the error.")
            )
        )
    )
    (exit (quiet))
)

(set #installmode
    (askbool
        (prompt "Choose the installation mode:")
        (help "Select Install if you want to install Warp3D, and Uninstall if you want to remove it. Warp3D is a hardware independent driver system for 3d accelerators.")
        (choices
            "Install"
            "Uninstall"
        )
        (default 1)
    )
)

(if (= #installmode 1)
    ; normal installation
    (
        (welcome (cat
            "Welcome to the Warp3D installation. This utility will install or "
            "update Warp3D, the hardware-independent 3D driver system, on your "
            "Amiga. ")
        )


        (message "The Installation program will now create a new directory \"Warp3D\" in your LIBS directory where the Warp3D libraries will be installed.")
        (makedir "Libs:Warp3D/")
        (makedir "Libs:Warp3D/GFXdrivers")
        (makedir "Libs:Warp3D/HWdrivers")
        ; --- Try to find out if WarpUp is installed.
        (if (exists "libs:Warp.library" (noreq))
            (set #ppc 1)
            (set #pcc 0)
        )
        (if (= #ppc 1)
            (set #result
                (askbool
                    (prompt "You seem to have WarpUp installed. Warp3D comes with a special PPC version that is usable for WarpUp applications. Do you want to install the PPC libraries, too?")
                    (help @askbool-help)
                    (choices "Yes" "No")
                    (default 1)
                )
            )
            (if (= #result 0)
                (set #ppc 0)
            )
        )
        (copylib
            (prompt "Copying the master library")
            (help @copylib-help)
            (source "libs/Warp3D.library")
            (dest "libs:")
        )
        (if (= #ppc 1)
            (copylib
                (prompt "Copying the PPC master library")
                (help @copylib-help)
                (source "libs/Warp3DPPC.library")
                (dest "libs:")
            )
        )

        (P_copy_single "libs/Warp3D/gfxdrivers/W3D_CyberGFX.library"
                       "libs:Warp3D/GFXdrivers"
                       "Copy CyberGraphX driver"
        )
        (if (= #ppc 1)
            (P_copy_single "libs/Warp3D/gfxdrivers/W3D_CyberGFX_PPC.library"
                           "libs:Warp3D/GFXdrivers"
                           "Copy CyberGraphX driver (PPC version)"
            )
        )
        (P_copy_single "libs/Warp3D/gfxdrivers/W3D_Picasso96.library"
                       "libs:Warp3D/GFXdrivers"
                       "Copy Picasso96 driver"
        )
        (if (= #ppc 1)
            (P_copy_single "libs/Warp3D/gfxdrivers/W3D_Picasso96_PPC.library"
                           "libs:Warp3D/GFXdrivers"
                           "Copy Picasso96 driver (PPC version)"
            )
        )


        ; Try to find out the graphics card
        (if (exists "devs:Monitors/CVision3D" (noreq))
            (set #graka 0)
            (set #graka -1)
        )
        ; Ask for graphics card
        (set #result
            (askchoice
                (prompt "Please select the graphics device you want to use.")
                (help @askchoice-help)
                (choices
                    "CyberVision64/3D"
                    "None of the above"
                )
                (default #graka)
            )
        )
        (select #graka
            (
                (set #grdrv "libs/Warp3D/HWdrivers/W3D_Virge.library")
                (set #grdrv2 "libs/Warp3D/HWdrivers/W3D_Virge_PPC.library")
            )
        )
        (copylib
            (prompt "Copying the hardware driver library")
            (help @copylib-help)
            (source #grdrv)
            (dest "libs:Warp3D/HWdrivers")
        )
        (if (= #ppc 1)
            (copylib
                (prompt "Copying the PPC hardware driver library")
                (help @copylib-help)
                (source #grdrv2)
                (dest "libs:Warp3D/HWdrivers")
            )
        )
        ; Ask for demo installation
        (set #result
            (askbool
                (prompt "Do you want to install the demo?")
                (help @askbool-help)
                (choices
                    "Yes"
                    "No"
                )
                (default 1)
            )
        )
        (if (= #result 1) (
                (set #demodest
                    (askdir
                        (prompt "Select a location to install the Demo. A Drawer \"W3DDemo\" will be created")
                        (help @askdir-help)
                        (newpath)
                        (default "ram:")
                    )
                )
                (if (NOT (exists #demodest))
                    (makedir #demodest)
                )
                (copyfiles
                    (source "demo/")
                    (dest (tackon #demodest "W3DDemo"))
                    (infos)
                    (all)
                    (optional "oknodelete" "force" "askuser")
                )
            )
        )
        (set #result
            (askbool
                (prompt "Do you want to Install the User's Guide?")
                (help @askbool-help)
                (choices
                    "Yes"
                    "No"
                )
                (default 1)
            )
        )
        (if (= #result 1)
            (
                (set #destdoc (askdir
                        (prompt "Select the place to install the documentation. A drawer \"docs\" will be created.")
                        (help @askdir-help)
                        (newpath)
                        (default "HELP:")
                    )
                )
                (copyfiles
                    (prompt "Copying documentation files")
                    (help @copyfiles-help)
                    (source "Docs")
                    (infos)
                    (all)
                    (dest (tackon #destdoc "Docs"))
                )
            )
        )

        (exit)
    )

    ; uninstall application

    (
        ; --- insert your code below ---
        (delete "libs:Warp3D.library" (optional "force"))
        (delete "libs:Warp3DPPC.library" (optional "force"))
        (delete "libs:Warp3D/GFXdrivers/#?" (optional "force"))
        (delete "libs:Warp3D/HWdrivers/#?" (optional "force"))
        (delete "libs:Warp3D/GFXdrivers" (optional "force"))
        (delete "libs:Warp3D/HWdrivers" (optional "force"))
        (delete "libs:Warp3D/" (optional "force"))
        ; -- end of your code ---

        (message "Uninstallation completed. The demo and documentation must be deleted manually.")

        (exit (quiet))
    )
)